activebar mousemenu deaktivieren ??

[erniepb]

Hallöchen
Ich hab folgendes kurzes Problem .. Wie deaktiviere ich das Mousemenu das normalerweise erscheint .. wenn man mit der rechten maustaste auf den activebar eines Forms klickt??

[toms]

Hi,

Was verstehst du unter 'activebar'?
Meinst du die Titelleiste?

[erniepb]

ja genau die ..

[toms]

Hi,

Dazu musst du einige Nachrichten abfangen:

Code:

type
  TForm1 = class(TForm)
  private
    procedure WMNcrButtonDown(var Msg: TMessage); message WM_NCRBUTTONDOWN;
    procedure WMSyscommand(var Msg: TWMSysCommand); message WM_SYSCOMMAND;
    procedure WMNCLButtonDblClk(var Msg: TMessage); message WM_NCLBUTTONDBLCLK;
  public
  end;

var
  Form1: TForm1;

implementation

{$R *.DFM}

// Rechte Maustaste auf Titelleiste unterdrücken.
procedure TForm1.WMNcrButtonDown(var Msg: TMessage);
begin
  if Msg.wParam = HTCAPTION then
    Msg.Result := 0;
end;

// Evtl Doppelklick auf App. Icon unterdrücken
procedure TForm1.WMNCLButtonDblClk(var Msg: TMessage);
begin
  if Msg.wParam = HTCAPTION then
    Msg.Result := 0;
end;

// Klick auf App. Icon unterdürcken
procedure TForm1.WMSyscommand(var Msg: TWMSysCommand);
begin
  case (Msg.CmdType and $FFF0) of
    SC_MOUSEMENU:
      Msg.Result := 0;
    else
      inherited;
  end;
end;

[erniepb]

Danke!! funktioniert gut !!!

Hab nur n kleines Problem .. ich versteh noch nich ganz was da an sich passiert .. hinsichtlich der verschiedenen Parameter ..
Ich denk ich werd mich da mal nach n entsprechenden Tutorial umsehen müssen ..

[toms]

Das beste "Tutorial" gibts hier:

http://msdn.microsoft.com/library/

[Luckie]

Also:
WM_NCRBUTTONDOWN ist ein Klick mit der rechten Maustaste in die NonClientAera des Fensters, also in den Nicht-Anwendungsbereich. der wParam der Nachricht ist das Ziel wohin geklickt wurde. Wurde auf die Titelleoste geklickt (HTCAPTION), wird die Nachricht umgebeogen bzw verschluckt, in dem nicht daraufreagiert wird.
Gleiche Vorgehen bei WM_NCLBUTTONDBLCLK.

Wird mit WM_SYSCOMMAND normalerweise das Mausmenü geöffnet, wird das auch wieder verschluckt.

[erniepb]

hui .. danke das hat geholfen ..

[Alfons_G]

Hallo Ernie,

eigentlich sind die Parameter von der Bezeichnung her recht aussagekräftig:
WM_NCRBUTTONDOWN = gedrückte rechte Maustaste
WM_SYSCOMMAND = Systemmenü
WM_NCLBUTTONDBLCLK = Doppelklick mit der linken Taste

Windows-Messages haben zwei Parameter wParam und lParam. Wenn der hier in Frage kommende Parameter HTCAPTION ist, war das Ziel der Aktion die Titelleiste. Durch Result := 0 wird die Message gelöscht. Das Fenster erfährt nichts mehr davon, dass seine Titelleiste angeklickt wurde.
Der Klick auf das Systemmenü muss anders behandelt werden, um nicht andere Aufrufe ebenfalls zu unterdrücken.
Weitergehende Infos dazu findest Du, wie toms schon schrieb, bei Microsoft - vor allem kannst Du dort alle möglichen Parameter nachschlagen.

Tutorials zu WinAPI kannst Du auf Luckies Homepage finden.

[Alfons_G]

Na, da war Luckie zur gleichen Zeit dran, wie ich