TEdit - Textbereich eingrenzen

[der_kumpel]

Hallo,


hab gerade ein Problem bei der Formulierung meines Problems,
darum verweise ich gleich mal auf das Bild im Anhang.

Wie kann ich also den Bereich von rechts "abgrenzen",
sodass das Eingabefeld ab dort zuende ist und rechts ein freier Bereich bleibt?

Kann mir jemand nen Tipp geben wie man da rangehen kann?
Könnt auch ne andere Komponente sein...


Danke schonmal,
kumpel

[DeddyH]

Meinst Du MaxLength?

[der_kumpel]

Danke für deinen Vorschlag, aber das ist es leider nicht.

Egal, wieviel in dem Edit drinsteht, es soll rechts immer ein Rand bleiben,
als ob dort schon das Edit zu Ende ist.

[DeddyH]

Ich kann es gerade nicht ausprobieren, aber ginge das evtl. durch künstliches Anfügen von Leerzeichen?

[Die Muhkuh]

Darf man erfahren, was das bringen soll?

[DeddyH]

Gut, das habe ich mich auch schon gefragt

[Die Muhkuh]

Zitat von DeddyH:

Gut, das habe ich mich auch schon gefragt

Dann hättest es halt mal geposted, Du Nase

[DeddyH]

[OT] Bei meinen Codes fragt man sich ja auch manchmal nach dem tieferen Sinn [/OT]

[toms]

Hallo

Um den Bereich rechts einzugrenzen, müssen wir die Grösse der NCA neu berechnen.
Wenn WM_NCCALCSIZE gesendet wird, machen wir die neue Berechnung.
Zusätzlich behandeln wir noch WM_NCPAINT, damit das normale Aussehen des Edits wieder
hergestellt wird.

Eine vereinfachte Komponente könnte so aussehen:

Delphi-Quellcode:

unit BorderEdit;

interface

uses
  Windows, Messages, Classes, Controls, StdCtrls, Graphics;

type
  TBorderEdit = class(TEdit)
  private
   procedure WMNCCalcSize(var Message: TWMNCCalcSize); message WM_NCCALCSIZE;
   procedure WMNCPaint(var Msg : TWMNCPaint); message WM_NCPAINT;
   procedure NCPaint(ACanvas : TCanvas);
  end;

procedure Register;

implementation

procedure Register;
begin
  RegisterComponents('Samples', [TBorderEdit]);
end;

procedure TBorderEdit.WMNCCalcSize (var Message: TWMNCCalcSize);
begin
  inherited;
  Dec(Message.CalcSize_Params^.rgrc[0].Right, 15);
end;

procedure TBorderEdit.NCPaint(ACanvas : TCanvas);
begin
  ACanvas.Pen.Color := clWindow;
  ACanvas.Brush.Color := clWindow;
  ACanvas.Rectangle(Rect(3,2, Width-2, Height-2));
end;

procedure TBorderEdit.WMNCPaint(var Msg: TWMNCPaint);
var
  Canvas : TCanvas;
  DC : HDC;
begin
  inherited;
  Canvas := TCanvas.Create;
  DC := GetWindowDC(Handle);
  try
    Canvas.Handle := DC;
    NCPaint(Canvas);
    Invalidate;
  finally
    ReleaseDC(Handle, DC);
    Canvas.Free;
  end;
end;

end.

[der_kumpel]

Genau das hab ich gemeint.

Vielen, vielen Dank, toms!

Edit, @ Die Muhkuh:
Da kommt eine CheckBox rein.