Kalenderwochen Funktion Falsch?

[Eppos]

Hallo zusammen,

ich benutze hier aus der Code-Lib folgende Funktion:

Hier zeigt Alex_ITA01 wie es möglich ist, anhand eines Datums die zugehörige Kalenderwoche zu ermitteln. Für Delphi 6 und höher, geht dies genau so gut mit WeekOfTheYear (Unit: DateUtils), doch für die Benutzer älterer Delphi-Versionen ist dies mit folgendem Code möglich:

Delphi-Quellcode:

function GetKW(Date: TDateTime): Integer; 
var 
   Day: Integer; 
   Y, M, D: Word; 
begin 
  Day := DayOfWeek(Date) - 1; 
  if (Day <= 0) then 
    Day := 7; 
  DecodeDate(Date + 4 - Day, Y, M, D); 

  result := round(((Date + 8 - Day) - EncodeDate(Y, 1, 1)) / 7); 
end;

Wenn ich aber diese verwende, wird mir die Kalenderwoche für den 10.01.2008 falsch berechnet?!
@Edit: Bekomme als Ergebnis '1', sollte aber 2 ausspucken...

Hat jemand eine Idee warum das so ist?

Ich habe die WeekOfTheYear Funktion nicht zur Verfügung!

Danke

[Eppos]

... ausser man beachtet, dass es sich um eine Deutsche KW/Datum handelt.

[negaH]

Also ich habe damals, und das schon zu Delphi 2 Zeiten, exakt diese Funktion entwickelt. Sie funktioniert richtig, teste mal

  ShowMessage(IntToStr(WeekOfDate(EncodeDate(2008, 1, 10)))); bei mir kommt da wie erwartet 2 raus.

Gruß Hagen

[x000x]

Moin moin,

mir ist gestern aufgefallen, dass diese funktion wohl doch fehlerhaft ist.
Das Problem liegt wohl hier:
((Date + 8 - Day) - EncodeDate(Y, 1, 1)) / 7 Folgender aufruf zeigt den Fehler:

Delphi-Quellcode:

ShowMessage(IntToStr(WeekOfDate(StrToDateTime('06.01.2010 11:59:59')))+#13#10+
            IntToStr(WeekOfDate(StrToDateTime('06.01.2010 12:00:00'))));

[Mithrandir]

Moin Peter,

stimmt, die Funktion ist nicht richtig. Hagens Funktion hingegen arbeitet tadellos.

[x000x]

Delphi-Quellcode:

function DayOfWeekGerman(ADate: TDateTime): Integer;
begin
  Result := DayOfWeek(ADate) -1;
  if Result <= 0 then Result := 7;
end;

function WeekOfDate(A: TDateTime): Integer;
var
  Day: Integer;
  Y,M,D: Word;
begin
  Day := DayOfWeekGerman(A);
  DecodeDate(A +4 -Day, Y, M, D);
  Result := Round(((A +8 -Day) - EncodeDate(Y, 1, 1)) / 7);
end;

procedure TForm1.Button1Click(Sender: TObject);
var dat : TDateTime;
begin
  ShowMessage(IntToStr(WeekOfDate(StrToDateTime('06.01.2010 11:59:59')))+#13#10+
              IntToStr(WeekOfDate(StrToDateTime('06.01.2010 12:00:00'))));
end;

ich komme hierbei leider zum selben ergebnis :-/

Schreibt man den Wert von ((A +8 -Day) - EncodeDate(Y, 1, 1)) / 7 in einen double, dann sieht man auch warum.

Bei '06.01.2010 11:59:59' ergibt dann ((A +8 -Day) - EncodeDate(Y, 1, 1)) / 7 = 1.4999983466 Bei '06.01.2010 12:00:00' ergibt dann ((A +8 -Day) - EncodeDate(Y, 1, 1)) / 7 = 1.5 und da Round(1.5) = 2 entsteht der Fehler.

[Mithrandir]

Dann sollte der Nachkommateil vielleicht lieber weggefiltert werden. Statt Round also Trunc

[Amateurprofi]

Zitat von Daniel G:

Dann sollte der Nachkommateil vielleicht lieber weggefiltert werden. :gruebel: Statt Round also Trunc

Nein, das bringt nichts.
Hagens Routine arbeitet fehlerfrei, solange der TDateTime Wert ganzzahlig ist.
Wenn der TDateTime-Wert einen Zeitanteil hat, bringt sie an bestimmten Tagen dann fehlerhafte Resultate, wenn der Zeitanteil >= 12 Stunden ist.
Also sollte am Anfang der Routine eine Zeile
A := Int(A); eingefügt werden.

Vielleicht sollte man die letzte Zeile ändern
von
Result := Round(((A +8 -Day) - EncodeDate(Y, 1, 1)) / 7); in
Result := Trunc(0.5+((A +8 -Day) - EncodeDate(Y, 1, 1)) / 7); weil das besser zeigt, was gerechnet werden soll.
M.E. sollte die Routine dann so aussehen:

Delphi-Quellcode:

function DayOfWeekGerman(ADate: TDateTime): Integer;
begin
  Result := DayOfWeek(ADate) -1;
  if Result <= 0 then Result := 7;
end;

function WeekOfDate(A: TDateTime): Integer;
var
  Day: Integer;
  Y,M,D: Word;
  n:extended;
begin
  A := Int(A);
  Day := DayOfWeekGerman(A);
  DecodeDate(A +4 -Day, Y, M, D);
  Result := Trunc(0.5+((A +8 -Day) - EncodeDate(Y, 1, 1)) / 7);
end;

[Mithrandir]

Zitat von Amateurprofi:

Nein, das bringt nichts.

Und im selben Posting machst du es dann doch.