Typecast von TObject zum Interface?

[sunny-andy]

Hallo liebe Leute,

seit Stunden suche ich eine Möglichkeit, ein TObject in ein Interface zu typecasten.

Ich habe für das Observer-Pattern eine Methode namens Aktualisieren, welche ein Objekt mitliefert.
Manchmal implementiert das mitgelieferte Objekt ein Interface (IFilterFrame), und dessen Methoden möchte ich dann gern ausführen:

Delphi-Quellcode:

{*
  Observer-Methode.
}
procedure TFrameKundenliste.Aktualisieren(Sender: TObject);
var
  FilterFrame: IFilterFrame;
begin
  if Supports(Sender, IFilterFrame) then
  begin
    FilterFrame := (Sender as IFilterFrame); // <- Funktioniert nicht!
    FilterFrame.DoSomething;
  end;

Was ich auch probiert habe, es gibt nur Fehler.
Habt ihr vielleicht einen Tipp für mich?

Danke!
Andy

[cruiser]

Rein theoretisch müsste das gehn...

Delphi-Quellcode:

procedure TFrameKundenliste.Aktualisieren(Sender: TObject);
var
  FilterFrame: IFilterFrame;
begin
  if Supports(Sender, IFilterFrame, FilterFrame) then
    FilterFrame.DoSomething;

{...}

[SirThornberry]

du schreibst das es nicht funktioniert und nur fehler gibt. Welche Fehler gibt es denn? Gibt es die Fehler erst beim ausführen oder schon beim compilieren?

[xaromz]

Hallo,

ich gebe mal einen Tipp ab: Du hast Deinem Interface keinen GUID verpasst. Das benötigt Delphi aber für "Supports" und "as". Übrigens muss bei meinem Delphi "Supports" nicht mit dem Interface, sondern mit dem GUID aufgerufen werden.

Gruß
xaromz

[efknarf]

Hallo,

Filterframe ist eine Variable des Typs IFrame, welche jedes beliebige Object speichern kann, das diesen Interface-Typ implementiert. Nun nehme ich an, daß du feststellen möchtest, ob das Object diese Schnittstelle unterstützt. Schaue dazu mal in der Hilfe unter:

* TObject.GetInterfaceEntry
* TObject.GetInterface
* TObject.GetInterfaceTable

Gruß

Frank

//Edit: Jedes Interface hat eine GUID. Falls bei der Deklaration keine angegeben wird, dann erstellt diese der Compiler.
//Edit2: Nachlesen konnte ich, daß ür eine GUID auch der Name des Interfaces angegeben werden kann. Der Compiler ersetzt diesen dann durch die GUID.

[sunny-andy]

Zitat von cruiser:

Rein theoretisch müsste das gehn...

Delphi-Quellcode:

procedure TFrameKundenliste.Aktualisieren(Sender: TObject);
var
  FilterFrame: IFilterFrame;
begin
  if Supports(Sender, IFilterFrame, FilterFrame) then
    FilterFrame.DoSomething;

{...}

Hallo, danke für eure Antworten. Das GUID hatte ich von Anfang an drin.
Die obige Antwort ist genau das, was ich gesucht habe. Es funktioniert wurderbar, dankeschön!

[Elvis]

Zitat von efknarf:

//Edit: Jedes Interface hat eine GUID. Falls bei der Deklaration keine angegeben wird, dann erstellt diese der Compiler.

Nein, wird nicht gehen.

Delphi-Quellcode:

program Blabla;

{$APPTYPE CONSOLE}

type
  IMyInterface = interface
  end;

  TMyClass = class(TInterfacedObject, IMyInterface)
  end;

var
  objRef  : TMyClass;
  intfRef : IMyInterface;
begin
  intfRef := objRef as IMyInterface;
end.

Zitat:

//Edit2: Nachlesen konnte ich, daß ür eine GUID auch der Name des Interfaces angegeben werden kann. Der Compiler ersetzt diesen dann durch die GUID.

Ja, der Typ eines Interfaces kann als GUID benutzt werden. (Das nutze ich zum Bleistift um Factories oder Services zu verwalten)
Aber auch das geht nur, wenn das Interface eine GUID bekam.
Tut ja auch nicht weh, Ctrl + Shift + G und schon hat man eine GUID.

[efknarf]

Hallo,

Stimmt! Mein Fehler. Dennoch sollte es mit der Funktion TObject.GetInterface gehen. Habe es eben ausprobiert.

Gruß

[shmia]

Das Mischen von Objekten und Interfaces kann unangenehme Folgen haben!!

Delphi-Quellcode:

procedure TFrameKundenliste.Aktualisieren(Sender: TObject); 
var 
  FilterFrame: IFilterFrame; 
begin 
  if Supports(Sender, IFilterFrame, FilterFrame) then 
  begin
    // intern wurde jetzt FilterFrame.AddRef aufgerufen
    // der Referenzzähler steht jetzt auf 1

    FilterFrame.DoSomething;
  end;

// jetzt gerät FilterFrame out-of-scope
// also wird FilterFrame.Release aufgerufen
// dann steht der Refernzzähler auf 0 und das Objekt wird freigegeben !!!
// es sei denn, man hat spezielle Maßnahmen getroffen, dass das nicht passiert
end;

[Elvis]

Zitat von shmia:

Das Mischen von Objekten und Interfaces kann unangenehme Folgen haben!!

In diesem Fall (bzw. jedem in dem Supports benutzt wird) schon.
Oft hat man aber eine Objektreferenz, bei der der Typ bereits ein bestimmtes Interface unterstützt.
Dann kann man problemlos die Objektreferenz an Methoden übergeben, die einen Interfacezeiger als "const" bekommen.

Delphi-Quellcode:

class procedure Miep.Mööp(const aInterfaceRef : IMyInterface);
begin
  aInterfaceRef.DoSomething();
end;  

var
  objectRef : TMyClass;
begin
  Miep.Mööp(objectRef);

Natürlich klappt das nicht mehr, wenn die Methode irgendwelche unkoscheren Dinge damit anstellt. (Zuweisen von Feldern, Weitergabe an Methode ohne "const", ...)