Ein TEdit als Ausgabe einer TComponent registrieren?

[ThE_-_BliZZarD]

Hallo liebe Gemeinde,

ich habe versucht eine Komponente zu erstellen, die z.B. bei einem bestimmten Ereignis eine ihrer in private deklarierten Variablen auf einem TEdit ausgeben soll. Mein Problem: Ich will das TEdit irgendwie registrieren, d.h. das man beim OnCreate das Main-Forms irgendwie einem Property meiner Komponente das TEdit "zuweisen" muss..

Delphi-Quellcode:

// in der Komponente
property Ausgabe: TEdit;
// im OnCreate
MeineKomponente.Ausgabe := Edit4;
// wieder in der Komponente nach dem Ereignis
Ausgabe.Text := 'blub!';

Ich hoffe ihr versteht was ich meine. Man kann ja auch Funktionen zuweisen, also müsste man dem Programm doch auch irgendwie verklickern könne, dass es auf mein TEdit zugreift..

Danke, freue mich auf Antworten ,

BliZZarD

[mkinzler]

Entweder als Verweis auf eine (private) Variable oder auf einen Setter.

property Ausgabe: String read FAusgabe ... bzw.

property Ausgabe: String read getAusgabe ...

[ThE_-_BliZZarD]

Ok sorry, schlecht formuliert:

Ich mein den Teil, wo das TEdit registriert wird, und dann darauf zugegriffen, denn das geht bei mir nicht (bzw weiß ich nicht wie es gehen soll).

[mkinzler]

Wie versuchst du es? Sollte so wie geschrieben gehen, halt mit TEdit statt String.

[ThE_-_BliZZarD]

ok, du scheinst noch nicht ganz verstanden zu haben, was ich nicht verstehe^^

Ich habe es momentan so probiert:

Delphi-Quellcode:

TThreadControl = class(TComponent)
     private
       FRunning: Integer;
       
       FOut_running: TEdit;
       procedure SetOutRunning(Value: TEdit);
     public
       property Running: Integer read FRunning;
     published
       property OUT_Running: TEdit read FOut_running write SetOutRunning;
       procedure NewThread();
end;

procedure TThreadControl.NewThread;
begin
   //ich weiß, hier fehlt noch eine ObzugewiesenAbfrage..^^
   FOut_running.Text := 'Test';
end;

procedure TThreadControl.SetOutRunning(Value: TEdit);
begin
   FOut_Running := Value;
end;

Mein Problem: Das geht nicht. Was mache ich falsch?

[scrat1979]

Habe grade das gesehen. Wenn ich Dich richtig verstanden habe, dann ist das genau das was Du suchst...
Das wird auch auf einem zugewiesenem TEdit ein Text ausgegeben!

dsdt.info - Tutorial

SCRaT

[mkinzler]

Zitat:

 //ich weiß, hier fehlt noch eine ObzugewiesenAbfrage..^^

if Assigned( FOut_running)

[DeddyH]

Und im Konstruktor nicht vergessen, mit nil zu initialisieren.

[efknarf]

Hallo,

habe mir das Tutorial angesehen. Fast denke ich, daß da etwas vergessen wurde. Aber ich kann mich auch irren. Hier mal ein Beispiel:

Delphi-Quellcode:

TTest = class(TComponent)
private
  FEdit: TEdit;
  procedure SetEdit(Value: TEdit);
protected
  procedure Notification(AComponent: TComponent; AOperation: TOperation); override;
public
  property Edit: TEdit read FEdit write SetEdit;
end;

implementation

{ Aufruf, wenn FEdit durch Destroy freigegeben wird }
procedure TTest.Notification(AComponent: TComponent; AOperation: TOperation);
begin
  inherited;
  if (AOperation = opRemove) and (FEdit = AComponent) then 
    FEdit:=nil;
end;

{ Setzen und TEdit registrieren }
procedure TTest.SetTest(Value: TEdit);
begin
  if FEdit <> Value then                               //nur, wenn sie sich unterscheiden
  begin
    if (FEdit <> nil) and (FEdit.Owner <> Self) then
      FEdit.RemoveFreeNotification(Self);              //eine vorhandene Registrierung aufheben
    FEdit:=Value;
    if (FEdit <> nil) and (FEdit.Owner <> Self) then
      FEdit.FreeNotification(Self);                    //diese Komponente bei FEdit registrieren
  end;
end;

Falls du mehr über diese beiden Methoden (FreeNotification und RemoveFreeNotification) wissen möchtest, dann schau bitte in der Hilfe nach. Sie dienen - kurz gesag - dazu, die Komponenten zu registrieren, damit sie sich gegenseitig über deren Freigabe informieren. Blöd ausgedrückt.
FreeNotification und RemoveFreeNotification müssen und dürfen nicht benutzt werden, wenn die Komponente TTest selbst schon Eigentümer von der TEDit-Komponente ist. In diesem Falle brauchst du die Setter-Methode total nicht und es funktioniert mit
  property Edit: TEdit read FEdit write FEdit; Die Prozedur Notification solltest du aber in jedem Falle implementieren. Denn sie sorgt dafür, daß das Feld FEdit mit nil initialisiert wird, falls deine FEdit-Komponente freigegeben wird.

Gruß

Frank