VirtualTreeView: Zugriff auf einzelnen Node

[MCXSC]

Hallo!

Ich habe eine kleine Frage bezüglich der VirtualTreeView-Komponente (bzw. des VST):

Und zwar gibt es ja bei der normalen TreeView und auch bei der ListView folgende Möglichkeit:

Delphi-Quellcode:

for i:=0 to ListView.Items.Count-1 do begin
 ShowMessage(ListView.Items[i].Caption);
end;

Zumindest so in etwa.

Allerdings habe ich bisher noch keine Möglichkeit gefunden, wie ich was vergleichbares auch mit der VST machen kann.

Hat jemand einen Tipp?

Danke & hf
MCXSC

[C.Schoch]

Hi,
Versuchs mal mit GetFirst, GetNext(), GetFirstChild() usw.

Um an die hinterlegten Daten Daten zu kommen benutzt du GetNodeData().

[MCXSC]

Ja, das habe ich ja schon. Aber auch das liefert mir nicht den direkten Zugriff auf einen bestimmten Node (z.B. den vierten Node in der Liste, o.ä.)

[generic]

welches ist denn der 4. Knoten? Muss die Liste dazu aufgeklappt oder zugeklappt sein?

[Wishmaster]

Hi

Delphi-Quellcode:

NodeX := Tree.FocusedNode.FirstChild;
for I:=0 to Tree.FocusedNode.ChildCount-1 do
begin
  if not Assigned(NodeX) then
    Exit;
  TreeData := Tree.GetNodeData(NodeX);
  // do something with TreeData here  <-
  NodeX := Tree.GetNextSibling(NodeX);
end;

[C.Schoch]

Hi,
So wie du das möchtest geht das im VT nicht, zumindest nicht direkt.
IMO geht das nur wenn du alle Nodes durchsuchst und dir im TreeData einen eigenen eindeutigen Bezeichner für den aktuellen Node anlegst und abfragst.

[MCXSC]

Ja, das es nur so geht, ist mir schon klar...

Aber wie kann ich denn die kompletten Node in der VST durchlaufen (von Index 0 an; also ohne das was ausgwählt ist, oder sonst was), von diesem übereinstimmenden den Index zurückgeben und den jeweiligen Node vorselektieren?

Ich bekomm es einfach nicht hin...

[MCXSC]

So, wie ich nun den Index des Node herausbekomme, weiß ich. Ich habs nun so gelöst (hab "TotalCount" gefunden ):

Delphi-Quellcode:

function FindeEintrag(Titel: String): Integer;
var
  Data: PTreeData;
  Node: PVirtualNode;
  i: Integer;
begin
  with MainFrm do begin
    Node := VSTListe.GetFirst;
    for i:=0 to VSTListe.TotalCount-1 do begin
      Data := VSTListe.GetNodeData(Node);
      if Data.Titel= Titelthen begin
        Result := Node.Index;
        Exit;
      end
      else Node := VSTListe.GetNext(Node);
    end;
  end;
end;

Aber nun stehe ich vor folgender Frage:

Wie kann ich diesen Node nun vorselectieren?

[hermannhass]

Fosusieren mit
focusednode:=node;
<dein node>
oder Selectieren mit
SelectNodes(node,node,false);

[semo]

hier ist eine Lösung die auch gleich Zwischenergebnisse überprüft:

Delphi-Quellcode:

function GetNodeByTitle(Titel: String): PVirtualNode;
var
  Data: PTreeData;
  Node: PVirtualNode;
begin
  Result := nil;
  with MainFrm do 
  begin
    Node := VSTListe.GetFirst();
    while Assigned(Node) and (Result = nil) do
    begin    
      Data := VSTListe.GetNodeData(Node);
      if Assigned(Data) and (Data.Titel= Titel) then      
        Result := Node;
      
      Node := VSTListe.GetNext(Node);
    end;
  end;
end;

Fokussieren des Nodes:

Delphi-Quellcode:

procedure Foo();
var
  MyNewFocusedNode: PVirtualNode;
begin
  MyNewFocusedNode := GetNodeByTitle('bla');
  if Assigned(MyNewFocusedNode) then
    VSTListe.FocusedNode := MyNewFocusedNode; 
end;