Teil eines ListView-Items färben

[Sharky]

Hai ihr,

irgendwie stehe ich auf dem Schlauch und brauche mal einen Denkanstoss.
Ich möchte die ersten x Buchstaben eines Items/Subitems von einem TListView färben (am liebsten die Hintergrundfarbe).
Das ganze Item ist ja kein Problem. Aber wie mache ich das mit nur einem Teil des Textes?

[mkinzler]

OwnerDraw

[Sharky]

Zitat von mkinzler:

OwnerDraw

Hai mkinzler,
das ist klar. Nur bekomme ich es nicht hin das nur ein Teil eines (Sub)Items eine andere Hintergrundfarbe bekommt.

[marabu]

Hai Stephan,

dieser Thread könnte den entscheidenden Hinweis enthalten: klick

Freundliche Grüße

[Sharky]

Zitat von marabu:

...dieser Thread könnte den entscheidenden Hinweis enthalten: ...

Danke. Das werde ich mir mal ansehen.

[Daniel]

Guten Morgen Sharky,


ich hatte gerade am Freitag für meinen Help-Booster eine ähnliche Routine geschrieben, hatte den Code jedoch im Büro, so dass ich ihn Dir erst jetzt zeigen kann. Er sollte eigentlich (fast) genau das machen, was Du brauchst:

Man gebe der Routine ein Canvas, einen Startpunkt, einen String sowie ein Teilstring daraus sowie die Farbe, in der der Teilstring unterlegt werden soll. Hinsichtlich der Geschwindigkeit kann man das mit Sicherheit optimieren, doch für meine Zwecke lange es. Hoffe, es hilft Dir ein wenig.

Delphi-Quellcode:

procedure myd( aCanvas : TCanvas; p : TPoint; aText : string; aSubString : string; HighlightColor : TColor );
var pPos : integer;
    oldC : TColor;
      p1 : string;
      p2 : string;
      p3 : string;
begin

  ///
  ///  Hintergrund loeschen
  aCanvas.FillRect( Rect(p.X, p.Y, p.X+aCanvas.TextWidth(aText) +2, p.Y+aCanvas.TextHeight(aText)) );

  pPos:= Pos( aSubString, aText );

  if pPos = 0 then
  begin
    ///
    ///  Teilstring nicht enthalten - Text einfach ausgeben
    aCanvas.TextOut( p.X, p.Y, aText );
  end
  else
  if pPos = 1 then
  begin
    ///
    ///  Teilstring steht am Anfang
    p1:= Copy( aText, 1, Length(aSubString) );
    p2:= Copy( aText, Length(aSubString) +1, Length(aText) );

    ///
    ///  Zuerst den farblich hinterlegten Teil ausgeben 
    oldC:= aCanvas.Brush.Color;
    SetBKMode( aCanvas.Handle, OPAQUE );
    aCanvas.Brush.Color:= HighlightColor;
    aCanvas.TextOut( p.X, p.Y, p1 );
    aCanvas.Brush.Color:= oldC;

    ///
    ///  Nun den nicht hinterlegten Teil ausgeben
    p.X:= p.X + aCanvas.TextWidth( p1 ) +1;

    SetBKMode( aCanvas.Handle, TRANSPARENT );
    aCanvas.TextOut( p.X, p.Y, p2 );
  end
  else
  begin
    ///
    ///  Teilstring mittendrin oder am Ende
    p1:= Copy( aText, 1, pPos-1 );
    p2:= Copy( aText, pPos, Length(aSubString) );
    p3:= Copy( aText, pPos + Length(aSubString), Length(aText) );

    SetBKMode( aCanvas.Handle, TRANSPARENT );
    aCanvas.TextOut( p.X, p.Y, p1 );

    p.X:= p.X + aCanvas.TextWidth( p1 ) +1;

    oldC:= aCanvas.Brush.Color;
    SetBKMode( aCanvas.Handle, OPAQUE );
    aCanvas.Brush.Color:= HighlightColor;
    aCanvas.TextOut( p.X, p.Y, p2 );
    aCanvas.Brush.Color:= oldC;

    if (p3 <> '') then
    begin
      SetBKMode( aCanvas.Handle, TRANSPARENT );
      p.X:= p.X + aCanvas.TextWidth( p2 ) +1;
      aCanvas.TextOut( p.X, p.Y, p3 );
    end;
  end;
end;