Klasse für data aware components (Data Controls)

[dfabian]

Jo hallo,

ich suche eine Klasse für data aware components (TDBEdit, TDBComboBox, etc.).

Ich möchte eine Message ausgeben, sobald ein Control die DataSource ds_test besitzt.
Jemand ne Idee?

Gruß
Daniel

[s-off]

Hallo,

Deine Anforderung verstehe ich nicht:

Gehe ich recht in der Annahme, dass sich zur Laufzeit die DataSource-Eigenschaft Deiner datensensitiven Komponenten ändert, und Du benachrichtigt werden möchtest, sobald bei einem der Controls die Datasource auf xxx gewechselt wird?

[dfabian]

Nein, ganz einfach. Auf einer Form hab ich mehere DB Controls und per klick auf einem Button möchte ich von jedem einzelnen DBControl auf der Form den Namen seiner DataSource per showMessage ausgeben.

[s-off]

Ohje, das konnte ich aus Deinem Eröffnungsthread nun wirklich gar nicht herauslesen

Also in dem Fall müsstest Du über sämtliche Komponenten Deiner Form iterieren und dann mittels der RTTI deren Eigenschaften abfragen.

Stichworte hier:
ComponentCount
PPropInfo
GetPropValue

Edit: Die RTTI-Methoden findet Du in der Unit 'TypInfo'.

[webcss]

oder, ohne RTTI, die Controls iterieren und dann
ShowMessage('Ich bin ' + Control.Datasource.Name + '! ;) ');

[dataspider]

Hi,

Ich denke, per RTTI ist der bessere Weg.
Hier ein Codeschnipsel zum Probieren:

Delphi-Quellcode:

uses
  TypInfo, DB...
...
procedure TForm1.Button1Click(Sender: TObject);
Var
  i: Integer;
  AObject: TObject;
Const
  PropName = 'DataSource';

begin
  for i := 0 to ControlCount - 1 do
  begin
    if IsPublishedProp(Controls[i], PropName) then
    begin
      AObject := GetObjectProp(Controls[i], PropName);
      if Assigned(AObject) then
        Memo1.Lines.Add(Controls[i].Name + ' = ' + (AObject as TDataSource).Name)
      else
        Memo1.Lines.Add(Controls[i].Name + ' = nil');
    end;
  end;
end;

Frank

[dfabian]

Schön, so ein Schnipsel...
Achso, danke nochmals. Wie soll ich sagen... it works!

[s-off]

Zitat von dfabian:

Schön, so ein Schnipsel...

Wenn man sie auch versteht schon. Ansonsten ist es effektiver, wenn man sich das Ganze anhand von Stichworten, die ja genannt worden sind, selber zusammensucht - so bleibt es besser im Gedächtnis

[dfabian]

Zitat von s-off:

Zitat von dfabian:

Schön, so ein Schnipsel...

Wenn man sie auch versteht schon. Ansonsten ist es effektiver, wenn man sich das Ganze anhand von Stichworten, die ja genannt worden sind, selber zusammensucht - so bleibt es besser im Gedächtnis

So siehts aus. Danke für den Denkanstoß.

[shmia]

Man kann auch ausgehend von der DataSource rückschliesen auf alle verbundenen DB aware Controls.
Diese Controls könnten ja auch auf einem anderen Formular oder Frame liegen.
Für jedes Control gibt es einen internen TDataLink.
Und das geht so:

Delphi-Quellcode:

type
   TDataSourceCracker=class(TDataSource);

procedure TForm1.Button1Click(Sender: TObject);
var
   dlist : TList;
   i : Integer;
   dlink : TDataLink;
   control : TComponent;
begin
   dlist := TDataSourceCracker(DataSource1).DataLinks;
   for i := 0 to dlist.Count-1 do
   begin
      dlink := TDataLink(dlist[i]);

      if dlink is TFieldDataLink then
      begin
         control := TFieldDataLink(dlink).Control;
         memo1.lines.add('Control: ' +control.GetNamePath+ ' Fieldname:'+TFieldDataLink(dlink).FieldName);
      end;
   end;
end;