Hallo Leute, ich bin neu hier bei Delphi-PRAXIS und hoffe, dass ihr mir mit diesem Problem weiterhelfen könnt. Ich muss zur Zeit eine ActiveX Komponente entwickeln und habe Probleme bei der Verwendung von Threads in ActiveX. In einer normalen Delphi Komponente tritt dieses Problem nicht auf.

Ich habe eine Delphi Komponente geschrieben, die eine Methode (StartThread) beinhaltet welche einen Thread (CamThread) startet. Dieser Thread löst alle 100ms Sekunden, über die Methode (UpdateLabel) einen Event aus. So weit funktioniert das ganze auch ohne Probleme. Wenn ich allerdings die Komponente in eine ActiveX Komponente umwandel funktioniert der Thread nicht mehr. Es kommen keine Events mehr alle 100ms aus der Komponente. Um sicherzugehen, dass es nicht die Events sind, die Probleme bereiten, habe ich noch eine Funktion hinzugefügt (StartEvent), die einen einzelnen Event auslöst. Diese funktioniert. Nur eben der Thread scheint in der Active X Komponente nicht zu laufen . Hier der Code:

zusammenfalten · markieren

Delphi-Quellcode:

interface

uses
  Windows, Messages, SysUtils, Classes, Controls;

type
  TCameraResultEvent = procedure(Sender: TObject) of object;
  TLTB = class(TWinControl)
  private
    FOnCameraResult: TCameraResultEvent;
    { Private-Deklarationen }
  protected
  public
    constructor Create(Owner: TComponent); override;
    procedure StartEvent;
    procedure StartThread;
  published
    property OnCameraResult : TCameraResultEvent
      read FOnCameraResult write FOnCameraResult;
  end;

  PTestRecord =^ TTestRecord;
  TTestRecord = record
    amin,amax,bmin,bmax,intensity,blueshift: Integer;
  end;

  CamThread = class(TThread)
  private
    procedure UpdateLabel;
  public
    constructor Create(CreateSuspended :boolean; TwinC: TLTB);
  protected
    procedure Execute; override;
  end;

procedure Register;

var
  List : TList;
  Thread : CamThread;
  TWin : TLTB;

implementation

constructor TLTB.Create(Owner: TComponent);
begin
  inherited Create(Owner); // Geerbten Konstruktor aufrufen.
  List := TList.Create;
  Thread := CamThread.Create(true,self);
end;

procedure CamThread.UpdateLabel;
begin
  TWin.StartEvent;
end;

constructor CamThread.Create(CreateSuspended :boolean; TwinC: TLTB);
begin
  inherited Create(CreateSuspended);
  TWin := TwinC;
end;

procedure CamThread.Execute;
var
  i: integer;
begin
  for i:=0 to 100000 do begin
    Synchronize(UpdateLabel);
    sleep(100);
  end;
end;

procedure TLTB.StartThread;
begin
  Thread.Resume;
end;

procedure TLTB.StartEvent;
var i : integer;
begin
    if Assigned(FOnCameraResult) then FOnCameraResult(self);
end;


procedure Register;
begin
  RegisterComponents('Beispiele', [TLTB]);
end;

end.

Ich würde mich riesig freuen , wenn mir da jemand weiterhelfen kann.
MfG Micha

hmm.. ist die Frage zu speziell, oder habe ich mich ungünstig ausgedrückt?
Ein bisschen Feedback wäre echt schön.
MFG Micha

Ich sehe in deinem Code kein ActiveX.
Ausserdem gibt es 3 globale Variablen (List : TList; Thread : CamThread; TWin : TLTB ).
Das ist sehr unschön!!!
Durch die Verwendung globaler Variablen, kann das Control nur einmal benützt werden.
Zumindest die Variable TWin kann leicht eliminiert werden, wenn man sie lokal in CamThread speichert.

markieren

Delphi-Quellcode:

  CamThread = class(TThread)
  private
     FTWin : TLTB; // <==

Hallo shmia. Danke für deine Antwort

ich habe hier nur den Code der normalen Delphi Komponente reingestellt. Den ActiveX Code der sich beim wandeln ergibt kann ich natürlich nachliefern. Allerdings wird der ja von Delphi automatisch generiert, somit gehe ich mal davon aus, dass dieser dann auch fehlerfrei ist.

Die drei globalen Variablen sind unschön das stimmt allerdings. Obwohl es ansich kein Problem wird, wenn ich das Control nur einmal verwenden könnte.
Die Variable List hat in dem Code keine verwendung und ist übrig geblieben, ich habe sie vergessen zu löschen.
Die anderen beiden Variablen habe ich global definiert weil ich nicht weiss wie ich die Methoden der beiden Klassen anders ansprechen kann.

Beispiel:
in der Methode CamThread.UpdateLabel will ich die Methode StartEvent der Klasse TLTB aufrufen. Wie kann ich das sonst machen ausser über die globale Variable TWin?

Andersherum weise ich der globalen Variable Thread eine Instanz der Klasse CamThread zu. Und das innerhalb meiner TLTB Klasse.
Gibt es da einen eleganteren Weg?

Ich empfinde diese Variante selber als sehr störend und würde mich über eine bessere Lösung natürlich freuen.

Moin moin,

Zitat von Oracle:

in der Methode CamThread.UpdateLabel will ich die Methode StartEvent der Klasse TLTB aufrufen. Wie kann ich das sonst machen ausser über die globale Variable TWin?

Das wäre evtl. so zu lösen:

zusammenfalten · markieren

Delphi-Quellcode:

//...
  TCameraResultEvent = procedure(Sender: TObject) of object;

  CamThread = class;

  TLTB = class(TWinControl)
  private
    { Private-Deklarationen }
    Thread : CamThread;
    FOnCameraResult: TCameraResultEvent;
  protected
    { Protected-Deklarationen }
  public
    { Public-Deklarationen }
    constructor Create(Owner: TComponent); override;
    procedure StartEvent;
    procedure StartThread;
  published
    { Published-Deklarationen }
    property OnCameraResult : TCameraResultEvent
      read FOnCameraResult write FOnCameraResult;
  end;

  PTestRecord =^ TTestRecord;
  TTestRecord = record
    amin,amax,bmin,bmax,intensity,blueshift: Integer;
  end;

  CamThread = class(TThread)
  private
    FWin : TLTB;
    procedure UpdateLabel;
  public
    constructor Create(CreateSuspended :boolean; TwinC: TLTB);
  protected
    procedure Execute; override;
  end;
//..
constructor CamThread.Create(CreateSuspended: boolean; TwinC: TLTB);
begin
  inherited Create(CreateSuspended);
  FWin := TwinC;
end;

Bei deinem ActiveX Problem kann ich dir nicht wirklich weiter helfen, aber
schau dir mal diesen Artikel (Delphi 6, 7 threads synchronization in ActiveX controls) an, vieleicht ist es ja das was du suchst?

Danke x000x !!!
Der Link, den du mitgeschickt hast, hat mich zur Lösung gebracht.
Ich habe einfach folgenden Code mit in meinen eigenen Code eingepflegt und dann ging es.
Das Problem waren die unterschiedlichen Thread Synchronisations Modelle von Delphi und ActiveX.
Vielen Dank. I freu mi!!

zusammenfalten · markieren

Delphi-Quellcode:

const
   WM_CLSYNCHRONIZE = WM_USER + 1;
...
type
   TActiveFormX = class(TActiveForm, IActiveFormX)
      procedure WMclSynchronize(var Message: TMessage);
      message WM_CLSYNCHRONIZE;
...
procedure TActiveFormX.ActiveFormCreate(Sender: TObject);
begin
   Classes.WakeMainThread := DoOnWakeMainThread;
end;

procedure TActiveFormX.DoOnWakeMainThread(Sender: TObject);
begin
   PostMessage(Self.Handle, WM_CLSYNCHRONIZE, 0, 0);
end;

procedure TActiveFormX.WMclSynchronize(var Message: TMessage);
begin
   Classes.CheckSynchronize();
end;