Verzeichnisse nach Dateien durchsuchen

[sakura]

So, oft gefragt und ab sofort als FAQ verfügbar (Luckie: ) ist eine einfache, rekursive Methode zum Suchen nach Dateien in Verzeichnissen.

Die Methode akzeptiert drei Parameter.

1. Das Startverzeichnis (mit oder ohne abschließenden Backslash)
2. (optional) Die Dateimaske, (Standard ist '*.*')
3. (Optional) True, wenn die Unterverzeichnisse durchsucht werden sollen, ansonsten False

Danke an Nailor für die Meldung eines Fehlers bei "nicht-rekursiver" Suche
Danke an JKuehl für die Meldung eines Fehlers bei "rekursiver" Suche
Danke an Tomektor für die Meldung eines Folge-Fehlers bei "rekursiver" Suche
Danke an J4N. AnsiLastChar-Konstrukt durch IncludeTrailingPathDelimiter ersetzt.
Danke an mirage228 fur die Meldung eines Flüchtigkeitsfehler, durch mich eingeführt aufgrund der vorangehenden Meldung.

Delphi-Quellcode:

//Nur eine der beiden Deklarationen, entsprechend der genutzen Delphiversion einsetzen !!!

// Deklaration bis einschließlich Delphi 4
procedure FindAllFiles(RootFolder, Mask: string; Recurse: Boolean);

// Deklaration ab Delphi 5
procedure FindAllFiles(RootFolder: string; Mask: string = '*.*'; Recurse: Boolean = True);

var
  SR: TSearchRec;
begin
  // Implementation bis einschließlich Delphi 4
  if RootFolder = '' then
    Exit;
  if AnsiLastChar(RootFolder)^ <> '\' then
    RootFolder := RootFolder + '\';

  // Implementation ab Delphi 5
  RootFolder := IncludeTrailingPathDelimiter(RootFolder);

  // * * * * *
  // nur bis einschließlich Delphi 4 benötigt
  if Mask = '' then
    Mask := '*.*';
  // * * * * *

  if Recurse then
    if FindFirst(RootFolder + '*.*', faAnyFile, SR) = 0 then
      try
        repeat
          if SR.Attr and faDirectory = faDirectory then
            // --> ein Verzeichnis wurde gefunden
            //   der Verzeichnisname steht in SR.Name
            //   der vollständige Verzeichnisname (inkl. darüberliegender Pfade) ist
            //       RootFolder + SR.Name
            if (SR.Name <> '.') and (SR.Name <> '..') then
              FindAllFiles(RootFolder + SR.Name, Mask, Recurse);
        until FindNext(SR) <> 0;
      finally
        FindClose(SR);
      end;
  if FindFirst(RootFolder + Mask, faAnyFile, SR) = 0 then
    try
      repeat
        if SR.Attr and faDirectory <> faDirectory then
        begin
          // --> eine Datei wurde gefunden
          //   der Dateiname steht in SR.Name
          //   der vollständige Dateiname (inkl. Pfadangabe) ist
          //       RootFolder + SR.Name

          // folgende Zeile schreibt den vollständigen Namen in eine Memo Feld des
          // Formulars Form1
          Form1.Memo1.Lines.Add(RootFolder + SR.Name);
        end;
      until FindNext(SR) <> 0;
    finally
      FindClose(SR);
    end;
end;

......

Ergänzung von Mr Luckie:
Das ganze noch mal ohne das hardgecodete Memo in der Prozedur und somit besser allgemein verwendbarer. Ich habe mir den Code in den letzten drei Tagen deswegen extra zwei mal umschreiben müssen.

Delphi-Quellcode:

procedure FindAllFiles(var FileList: TStrings; RootFolder: string; Mask: string =
  '*.*'; Recurse: Boolean = True);

var
  SR: TSearchRec;
begin
  RootFolder := IncludeTrailingPathDelimiter(RootFolder);

  if Recurse then
    if FindFirst(RootFolder + '*.*', faAnyFile, SR) = 0 then
    try
      repeat
        if SR.Attr and faDirectory = faDirectory then
            // --> ein Verzeichnis wurde gefunden
            //   der Verzeichnisname steht in SR.Name
            //   der vollständige Verzeichnisname (inkl. darüberliegender Pfade) ist
            //       RootFolder + SR.Name
          if (SR.Name <> '.') and (SR.Name <> '..') then
            FindAllFiles(FileList, RootFolder + SR.Name, Mask, Recurse);
      until FindNext(SR) <> 0;
    finally
      FindClose(SR);
    end;
  if FindFirst(RootFolder + Mask, faAnyFile, SR) = 0 then
  try
    repeat
      if SR.Attr and faDirectory <> faDirectory then
      begin
          // --> eine Datei wurde gefunden
          //   der Dateiname steht in SR.Name
          //   der vollständige Dateiname (inkl. Pfadangabe) ist
          //       RootFolder + SR.Name
        FileList.Add(RootFolder + SR.Name);
      end;
    until FindNext(SR) <> 0;
  finally
    FindClose(SR);
  end;
end;

[edit=Luckie]Code ergänzt. Mfg, Luckie[/edit]

[CalganX]

mirage228 hat noch auf folgendes hingewiesen:

Zitat von mirage228:

Mir ist ein kleiner Fehler aufgefallen:
IncludeTrailingPathDelimiter(RootFolder); Erstmal ist IncludeTrailingPathDelimiter eine Funktion, die das Ergebnis im Rückgabewert hat und außerdem gibt sie erst ab Delphi 4 oder höher (genauso, wie IncludeTrailingBackslash)

Ich verwende dabei diesen Code, der dem dort oben recht ähnlich ist:

Delphi-Quellcode:

procedure FileList(const APath, AExt: string; ARecurse: Boolean;
  AList: TStrings);
var
  F    : TSearchRec;
  Path : string;
begin
  Path := IncludeTrailingPathDelimiter(APath); // nur für Delphi 4 und höher!
  if (ARecurse) and
    (FindFirst(Path + '*.*', faAnyFile, F) = 0) then
  try
    repeat
      if (F.Name <> '.') and (F.Name <> '..') and
        ((F.Attr and faDirectory) = faDirectory) then
        FileList(Path + F.Name, AExt, ARecurse, AList);
    until FindNext(F) <> 0;
  finally
    FindClose(F);
  end;
  if FindFirst(Path + AExt, faAnyFile, F) = 0 then
  try
    repeat
      if (F.Name <> '.') and (F.Name <> '..') and
        ((F.Attr and faDirectory) <> faDirectory) then
        AList.Add(Path + F.Name);
    until FindNext(F) <> 0;
  finally
    FindClose(F);
  end;
end;

[CalganX]

SirThornberry hat diese Methode noch ein wenig beschleunigt. Der entsprechende SourceCode ist hier zu finden.

[Matze]

Von xX0815Xx gibt es eine erweiterte Funktion, die eine Suche nach mehreren Masken ermöglicht.