ZEOS TZSqlProcessor verarbeitet MetaScript nicht komplett

[Satty67]

Hallo,

z.Z. versuche ich die (FireBird) Datenbank-Tabellen, Trigger und CO. automatisch per MetaScript zu erstellen. Dazu verwende ich von Zeos den TZSqlProcessor.

Delphi-Quellcode:

function RunScript(AOwner : TComponent; Connection : TZConnection; Script : TStringList): String;
var
  SqlProcessor : TZSqlProcessor;
begin
  Result := '';
  SqlProcessor := TZSqlProcessor.Create(aOwner);
  try
    SqlProcessor.Connection := Connection;
    SqlProcessor.DelimiterType := dtSetTerm;
    SqlProcessor.Script.Assign(Script);
    try
      SqlProcessor.Execute;
    except
       on E:Exception do Result := E.Message;
    end;
  finally
    SqlProcessor.Free;
  end;
end;

Jetzt werden immer nur drei SQL Anweisungsblöcke abgearbeitet, beim 4. Anweisungsblock bricht TZSqlProcessor ab mit

Code:

SQL Error:  Dynamic SQL Error SQL error code = -901 invalid transaction handle (expecting explicit transaction start). Error Code: -901. Unsuccessful execution caused by system error that does not preclude successful execution of subsequent statements The SQL: <Code der 4. SQL-Anweisung>

Die jeweilige SQL-Anweisung scheint irrelevant, da Umsortieren immer die Exception beim 4. Block auslöst (lege mein Test-Script trotzdem mal in die Anlage). TZSqlProcessor.Parse und anschließende Abfrage von Count gibt die korrekte Anzahl der Anweisungs-Blöcke wieder.

Ich bin mit dem Fehler etwas überfordert... scheinbar wird das Transaktions-Handle nach dem 3. Block geschlossen und führt dann beim 4. zum Fehler?

Die Tabellen lassen sich problemlos "einzeln" anlegen, also wenn ich für jede Tabelle und für jeden Trigger einen einzelnen Aufruf starte. Aber das kann ja nicht die Lösung sein...

[haentschman]

Guten Abend

Ich hab zwar noch nicht mit dem SQLProcessor gearbeitet aber du hast nach der 3. Anweisung ein Commit stehen.

- vieleicht läuft alles in einer Transaktion ?
- durch das Commit schließt du ab und deine 4. Anweisung hat keine Transaktion
- muß das Commit da sein ?

...nur so als schnelle Ideen

[edit]
das mit dem Commit sollte eigentlich so sein. Wenn die Tabellen nicht committed sind kannst du keine Generatoren etc. anlegen oder ?
[/edit]

[Satty67]

Danke, denke das war der richtige Ansatz.

Commit Work scheint den Fehler zu verursachen, also die Transaktion zu beenden, womit das Script dann wohl in einer Transaktion ablaufen soll.

€: Jetzt kommt der Fehler, das "Set Term" unbekannt ist. Das ist offensichtlich eine Fehlermeldung des Parsers. Wenn ich das jetzt richtig überblicke, dann kann SQLProcessor nur mit einem Terminator umgehen und diesen auch nicht innerhalb des Script umschalten.

Entweder bin ich noch nicht reif für SQL oder Zeos ist nicht ausgereift. Ich gebe auf und parse das MetaScript selbst. Ist nicht so schwer, nur Delimiter beachten und per Query einzeln abschicken.

[Satty67]

So, hier meine vorübergehende Lösung des Problems, dass TZSqlProcessor "SET TERM" nicht richtig ausgewertet hat (obwohl es das mit mtSetTerm sollt).

Das ganze noch als Function. Packe das am Ende des Projektes noch in eine Klasse und baue ein Rollback ein (wenn Zeos das zulässt)

Delphi-Quellcode:

uses
  SysUtils, Classes, ZConnection, ZDataSet;

// Execute a MetaScript (e.g. from FlameRobin)
// Result is empty if no error else contains the TZQuery exception message
function ExecuteMetaScript(AOwner : TComponent; Connection : TZConnection; Script : TStringList): String;

  function TermChanged(Sql : String; var Term : Char): Boolean;
  var
    Part : String;
  begin
    Result := False;
    Part := UpperCase(Trim(Sql));
    if Pos('SET', Part) = 1 then begin
      Part := Trim(Copy(Part, 4, 1024));
      if Pos('TERM', Part) = 1 then begin
        Part := Trim(Copy(Part, 5, 1024));
        if Part <> '' then begin
          Term := Part[1];
          Result := True;
        end;
      end;
    end;
  end;

const
  SqlTerm : Char = ';';
var
  i : Integer;
  Term : Char;
  Query : TZQuery;
begin
  Result := '';
  Term := SqlTerm;
  Query := TZQuery.Create(AOwner);
  try
    Query.Connection := Connection;
    for i := 0 to Script.Count - 1 do begin
      // SET TERM prüfen und gleichzeitig ausklammern
      if not TermChanged(Script[i], Term) then begin
        if Term <> SqlTerm then
          Query.SQL.Add(StringReplace(Script[i], Term, SqlTerm, [rfReplaceAll]))
        else
          Query.SQL.Add(Script[i]);
        if Pos(Term, Script[i]) > 0 then begin
          try
            Query.ExecSQL;
          except
            on E: Exception do Result := E.Message;
          end;
          Query.SQL.Clear;
        end;
      end;
    end;
  finally
    Query.Free;
  end;
end;

Ein relativ komplexes MetaScript mit Triggern von FlameRobin wurde sauber verarbeitet.

Falls jemand einen Fehler sieht, bitte mitteilen, korrigiere das dann spätestens beim Anlegen der Klasse.

Wenn jemand ein funktionierenden Code hat, der FlameRobin-MetaScripte (oder vergleichbare) mit "SET TERM" (Trigger, Procedures) via TZSqlProcessor verarbeiten kann, auch her damit